(define-module (elenq documentation)
  #:use-module (elenq graphics)
  #:use-module ((guix licenses) #:prefix license:)
  #:use-module (guix build-system copy)
  #:use-module (guix gexp)
  #:use-module (guix git-download)
  #:use-module (guix packages)
  #:use-module (gnu packages haskell-xyz))

(define-public pandoc-templates
  (let ((revision "1")
        (commit "8bc6f1eab3288c3a6ae15a050c8d9fd84aacbf47"))
    (package
      (name "pandoc-templates")
      (version (git-version "0.0.0" revision commit))
      (source
        (origin
          (method git-fetch)
          (uri (git-reference
                 (url "git://git.elenq.tech/pandoc-templates")
                 (commit commit)))
          (sha256
            (base32 "0yyyyjq5022qisbf5yxxd65hjg79y6bkz32qv8xas40riv9sghzd"))))
      (build-system copy-build-system)
      (inputs (list elenq-logos))
      (arguments
        (list
          #:install-plan ''(("pandoc" "/share/pandoc"))
          #:phases
          #~(modify-phases %standard-phases
             (add-before 'install 'set-url
               (lambda _
                 (for-each
                   (lambda (f)
                     (substitute* f
                       (("\\$elenq-directory\\$")
                        (string-append #$elenq-logos "/share/elenq/"))))
                   (list "pandoc/templates/elenq-article.latex"
                         "pandoc/templates/elenq-book.latex")))))))
      (native-search-paths
        (list (search-path-specification
                (variable "XDG_DATA_DIRS") ;; Not supported by pandoc _yet_
                (files '("share")))))
      (home-page "http://git.elenq.tech/pandoc-templates")
      (synopsis "Pandoc templates for ElenQ Technology")
      (description "A set of well configured Pandoc templates for ElenQ
Technology's documents.")
      (license license:asl2.0))))


(define-public elenqdoc
  (let ((revision "1")
        (commit "1cb21742a69f681e6452a7ddd0adc9543aefd72a"))
    (package
      (name "elenqdoc")
      (version (git-version "0.0.0" revision commit))
      (source
       (origin
         (method git-fetch)
         (uri (git-reference
               (url "git://git.elenq.tech/elenqdoc")
               (commit commit)))
         (sha256
          (base32 "0fdxskf3h14vdr9w5pi18svrz40p9qkbwcn4c4rp1b1azpbfsa6s"))))
      (build-system copy-build-system)
      (inputs (list pandoc-templates))
      (propagated-inputs (list pandoc))
      (arguments
       (list
        #:install-plan ''(("elenqdoc" "/bin/elenqdoc"))
        #:phases #~(modify-phases %standard-phases
                     (add-after 'install 'wrap
                       (lambda _
                         (wrap-program (string-append #$output "/bin/elenqdoc")
                           `("ELENQDOC_DATADIR" =
                             (,(string-append #$pandoc-templates
                                              "/share/pandoc/")))))))))
      (home-page "http://git.elenq.tech/")
      (synopsis "Simplified pandoc wrapper for ElenQ documents")
      (description "Provides `elenqdoc` command.")
      (license license:asl2.0))))